;
; $VER: Installer script 1.0 for mds fusion libraries (18.12.2006)
;
; Author: dOc.K / mdS
;
; --------------------------------------------------------

(set #intro1 "\nInstallation of needed libraries if they are not yet present.\n\n")
(set #intro2 "dbplayer.library (Sebastian Jedruszkiewicz)\n")
(set #intro3 "guigfx.library and render.library (TEK neoscientists)\n")
(set #intro4 "wizard.library (HAAGE & PARTNER Computer GmbH)\n\n")

(set #wrong_os "Fusion needs at least OS 3.0 to run.\n")
(set #wrong_cpu "Fusion needs at least a 68020 CPU to run.\n")

(set #dbplayer_msg "\nCopying dbplayer.library ...")
(set #guigfx_msg "\nCopying guigfx.library ...")
(set #render_msg "\nCopying render.library ...")
(set #wizard_msg "\nCopying wizard.library ...")

(set #done "\nInstallation complete.\n")

; --------------------------------------------------------

(if (= @language "deutsch")
(
(set #intro1 "\nInstallation der benötigten Bibliotheken, falls nicht bereits vorhanden.\n\n")
(set #intro2 "dbplayer.library (Sebastian Jedruszkiewicz)\n")
(set #intro3 "guigfx.library und render.library (TEK neoscientists)\n")
(set #intro4 "wizard.library (HAAGE & PARTNER Computer GmbH)\n\n")

(set #wrong_os "Fusion setzt mindestens OS 3.0 voraus.\n")
(set #wrong_cpu "Fusion benötigt mindestens einen 68020 Prozessor.\n")

(set #dbplayer_msg "\nKopieren der dbplayer.library ...")
(set #guigfx_msg "\nKopieren der guigfx.library ...")
(set #render_msg "\nKopieren der render.library ...")
(set #wizard_msg "\nKopieren der wizard.library ...")

(set #done "\nInstallation komplett.\n")
)
)

; --------------------------------------------------------

(welcome #intro1 #intro2 #intro3 #intro4)

; --------------------------------------------------------

(set #os_ver (getversion "exec.library" (resident)))
(if (< #os_ver (* 39 65536)) (abort #wrong_os))

(set #cpu_type (database "cpu"))
(if (< #cpu_type "68020") (abort #wrong_cpu))

; --------------------------------------------------------

(complete 0)

(copylib
    (source "install/dbplayerlib/dbplayer.library") (dest "LIBS:")
    (prompt #dbplayer_msg) (confirm) (help @copylib-help)
)

(complete 25)

(copylib
    (source "install/guigfxlib/libs/guigfx.library") (dest "LIBS:")
    (prompt #guigfx_msg) (confirm) (help @copylib-help)
)

(complete 50)

(copylib
    (source "install/renderlib/libs/render.library") (dest "LIBS:")
    (prompt #render_msg) (confirm) (help @copylib-help)
)

(complete 75)

(copylib
    (source "install/wizardlib/wizard.library") (dest "LIBS:")
    (prompt #wizard_msg) (confirm) (help @copylib-help)
)

(complete 100)

; --------------------------------------------------------

(exit #done (quiet))
