	;
	; 1942 joke
	;
	ORG $1001-2
	DW  $1001		; file header
	;
CurCol		= $053B
Plot		= $FFF0
Print		= $FF4F
	;
	DW $100B,0
	DB $9E,"4109",0,0,0	; SYS4109
	;
start   
	SEI
	LDX #irq & 255
	LDY #irq >> 8
	STX $0314
	STY $0315
	LDA #$02
	STA $FF0A 
	LDA #$BC
	STA $FF0B		; set up irq
	JSR PLAYER_INIT
	LDA #$00
	STA $FF15
	STA $FF19		; turn screen black
	LDA $FF07
	ORA #$10
	STA $FF07		; multicolour on
	LDA $FF12
	AND #$FB
	STA $FF12		; look at RAM for chars
	LDA $FF13
	AND #$03
	ORA #$38
	STA $FF13		; chars at $3800
	LDA #$35
	STA $FF16
	LDA #$55
	STA $FF17		; set up multicolour colours
	CLC
	LDX #$00		; start displaying title screen...
	LDY #$04
	LDA #$77
	JSR PrePrint
	JSR Print
	DB "SCORE",0
	LDY #$0D
	LDA #$43
	JSR PrePrint
	JSR Print
	DB "LIVES",0
	LDY #$15
	LDA #$44
	JSR PrePrint
	JSR Print  
	DB "ROLLS",0
	LDY #$1C
	LDA #$77
	JSR PrePrint
	JSR Print
	DB "HIGH SCORE",0
	INX
	LDY #$03
	LDA #$71
	JSR PrePrint
	JSR Print
	DB "0000000",0
	LDY #$0E
	LDA #$45
	JSR PrePrint
	JSR Print
	DB "@@@",0
	LDY #$16
	LDA #$42
	JSR PrePrint
	JSR Print
	DB "RRR",0
	LDY #$1E
	LDA #$71
	JSR PrePrint
	JSR Print
	DB "0040000",0
	LDX #$09		; print 1942 logo
	LDY #$08
	LDA #$79
	JSR PrePrint
	JSR Print
	DB $60,$61,$62,$63,"  ",$60,$61,$64,$65,$66,$67," ",$68,$69,$62,$6A," ",$6B,$62,$64,$6C,$6D,$6E
	DB "                "
	DB $6F,$70,$71,$72,"  ",$73,$74,$75,$76,$77,$78,$79,$7A,$7B,$74,$7C," ",$7D,$7E,$7F,$A0,$74,$A1
	DB "                "
	DB $A2,$A3,$A4,$72,"  ",$A5,$A6,$A7,$A8,$A9,$78,$AA,$AB,$AC,$74,$AD,$AE,$AF,$B0,$B1,$B2,$B3,$B4
	DB "                 "
	DB $B5,$B6,$72,$B7," ",$B8,$B9,$BA,$BB,$A9,$78,$BC,$BD,$BE,$74,$BF,$5B,$5C,$5D,$5E,$5F,$21,$22
	DB "                "
	DB $23,$24,$25,$26,$27," ",$28,$25,$29,$25,$2A,"  ",$2B,$2C,$2D,$2E,$2F,$3A,$3B,$3C,$2D,$2D,$2F
	DB "                "
	DB $3D,$3D,$3D,$3D,"  ",$3D,$3D,$3D,$3E,"   ",$3F,$3D,$3D,$5A," ",$3D,$3D,$3D,$3D,$3D,0
	; logo end
	LDX #$15
	LDY #$0F
	LDA #$56
	JSR PrePrint
	JSR Print
	DB "PRESS FIRE",0
	CLI
fire	LDA #$FF
	STA $FD30
	LDA #$FB
	STA $FF08
	LDA $FF08
	AND #$40		; check fire 1
	BEQ crash
	LDA #$FF
	STA $FD30
	LDA #$FD
	STA $FF08
	LDA $FF08
	AND #$80		; check fire 2
	BNE fire
crash	SEI
	LDY #$00
	STY $FF11		; sound off
	LDX #$05
	LDA #$71
	JSR PrePrint
	JSR Print
	DB "BREAK",13
	DB "   PC  SR AC XR YR SP",13
	DB "; APR1 LF 00 L5 20 07",0
loop	JMP loop	

PrePrint	
	STA CurCol		; set cursor color from acc
	JSR Plot		; set cursor position from X and Y regs
	RTS
irq
	LDA $FF09
	STA $FF09
	JSR PLAYER
	PLA
	TAY
	PLA
	TAX
	PLA
	RTI
	
	ORG $1400
	include "LODPLAY.ASM"
	
	ORG $1800
	include "1942TUNE.ASM"
	
	ORG $2000
	include "1942CHAR.ASM"	;
				;
	ORG $2800		;
	include "1942CHAR.ASM"	; spam the ram,
				; make the tape loader a bit longer :)
	ORG $3000		;
	include "1942CHAR.ASM"	;
	
	ORG $3800
	include "1942CHAR.ASM"
	